"=============================================================================
" haxe.vim --- haxe language support for SpaceVim
" Copyright (c) 2016-2022 Wang Shidong & Contributors
" Author: Wang Shidong < wsdjeg@outlook.com >
" URL: https://spacevim.org
" License: GPLv3
"=============================================================================

""
" @section lang#haxe, layers-lang-haxe
" @parentsection layers
" This layer is for haxe development, disabled by default, to enable this
" layer, add following snippet to your SpaceVim configuration file.
" >
"   [[layers]]
"     name = 'lang#haxe'
" <
"
" @subsection layer options
"
" 1. `haxe_interpreter`: Set the haxe interpreter, by default, it is `haxe`
" >
"   [[layers]]
"     name = 'lang#haxe'
"     haxe_interpreter = 'path/to/haxe'
" <
"
" @subsection Key bindings
" >
"   Mode            Key             Function
"   ---------------------------------------------
"   normal          SPC l r         run current file
" <
"
" This layer also provides REPL support for haxe, the key bindings are:
" >
"   Key             Function
"   ---------------------------------------------
"   SPC l s i       Start a inferior REPL process
"   SPC l s b       send whole buffer
"   SPC l s l       send current line
"   SPC l s s       send selection text
" <
"

if exists('s:haxe_interpreter')
  finish
endif

let s:haxe_interpreter = 'haxe'
let s:haxe_repl = 'haxe-repl'

function! SpaceVim#layers#lang#haxe#plugins() abort
  let plugins = []
  call add(plugins, [g:_spacevim_root_dir . 'bundle/vim-haxe', {'merged' : 0}])
  return plugins
endfunction

function! SpaceVim#layers#lang#haxe#config() abort
  call SpaceVim#plugins#repl#reg('haxe', s:haxe_repl)
  call SpaceVim#plugins#runner#reg_runner('haxe', s:haxe_interpreter . ' --main %s --interp')
  call SpaceVim#mapping#space#regesit_lang_mappings('haxe', function('s:language_specified_mappings'))
endfunction

function! SpaceVim#layers#lang#haxe#set_variable(var) abort
  let s:haxe_interpreter = get(a:var, 'haxe_interpreter', s:haxe_interpreter)
endfunction

function! s:language_specified_mappings() abort
  call SpaceVim#mapping#space#langSPC('nmap', ['l','r'], 'call SpaceVim#plugins#runner#open()', 'execute current file', 1)
  let g:_spacevim_mappings_space.l.s = {'name' : '+Send'}
  call SpaceVim#mapping#space#langSPC('nmap', ['l','s', 'i'],
        \ 'call SpaceVim#plugins#repl#start("haxe")',
        \ 'start REPL process', 1)
  call SpaceVim#mapping#space#langSPC('nmap', ['l','s', 'l'],
        \ 'call SpaceVim#plugins#repl#send("line")',
        \ 'send line and keep code buffer focused', 1)
  call SpaceVim#mapping#space#langSPC('nmap', ['l','s', 'b'],
        \ 'call SpaceVim#plugins#repl#send("buffer")',
        \ 'send buffer and keep code buffer focused', 1)
  call SpaceVim#mapping#space#langSPC('nmap', ['l','s', 's'],
        \ 'call SpaceVim#plugins#repl#send("selection")',
        \ 'send selection and keep code buffer focused', 1)
endfunction

function! SpaceVim#layers#lang#haxe#health() abort
  call SpaceVim#layers#lang#haxe#plugins()
  call SpaceVim#layers#lang#haxe#config()
  return 1
endfunction
