mirror of
https://github.com/SpaceVim/SpaceVim.git
synced 2025-02-03 10:20:04 +08:00
38 lines
1.1 KiB
Scheme
38 lines
1.1 KiB
Scheme
[
|
|
; ... refers to the portion that this indent query will have effects on
|
|
(class_body) ; { ... } of `class X`
|
|
(enum_body) ; { ... } of `enum X`
|
|
(interface_body) ; { ... } of `interface X`
|
|
(constructor_body) ; { `modifier` X() {...} } inside `class X`
|
|
(annotation_type_body) ; { ... } of `@interface X`
|
|
(block) ; { ... } that's not mentioned in this scope
|
|
(switch_block) ; { ... } in `switch X`
|
|
(array_initializer) ; [1, 2]
|
|
(argument_list) ; foo(...)
|
|
(formal_parameters) ; method foo(...)
|
|
(annotation_argument_list) ; @Annotation(...)
|
|
(element_value_array_initializer) ; { a, b } inside @Annotation()
|
|
] @indent.begin
|
|
|
|
(expression_statement (method_invocation) @indent.begin)
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @indent.branch
|
|
|
|
(annotation_argument_list ")" @indent.end) ; This should be a special cased as `()` here doesn't have ending `;`
|
|
"}" @indent.end
|
|
|
|
(line_comment) @indent.ignore
|
|
|
|
[
|
|
(ERROR)
|
|
(block_comment)
|
|
] @indent.auto
|
|
|